UO Steam Scripts

Joined
Mar 13, 2018
Messages
45
Likes
4
#1
Post your UO Steam script here! Name your threads accordingly. Provide credit where due.
 
Joined
Mar 13, 2018
Messages
45
Likes
4
#2
Sort enMass

This will help you sort your loot into predefined secures in your house. It is by catagory. You may need to add items from time to time since that's what I've done and I know I've missed some types. You can also copy paste out sections to make specific sorter subscripts as needed.
Jewels and hammers have been excluded on purpose, since I deal with them differently.
 

Attachments

Joined
Mar 13, 2018
Messages
45
Likes
4
#3
Blacksmith Bod Filler

Will fill all blacksmith smalls from one book and deposit them into another. You will need two bod books, a secure with resources, and tinkering skill to make tools.
 

Attachments

Joined
Mar 13, 2018
Messages
45
Likes
4
#4
Tailor Bod Filler

Will fill all tailor smalls from one book and deposit them into another. You will need two bod books, a secure with resources, and tinkering skill to make tools.
 

Attachments

Joined
Mar 13, 2018
Messages
45
Likes
4
#5
Carpentry Bod Filler

Will fill all carpentry smalls from one book and deposit them into another. You will need two bod books, a secure with resources, and tinkering skill to make tools.
 

Attachments

Joined
Mar 13, 2018
Messages
45
Likes
4
#6
BOD Transfer Book-to-book

Will allow you to move bods from one book to another. Can crash your client if you use filters - no way around this.
 

Attachments

Joined
Mar 13, 2018
Messages
45
Likes
4
#7
BOD Redeemer

This is for resetting your .1 bods with your main crafter. Will exchange bods from a sourcebook, and deposit new empty bods into a destination. It will automatically bank the points so don't do this on bods you intend to use for rewards.
 

Attachments

Joined
Mar 13, 2018
Messages
45
Likes
4
#8
Sort Blacksmithing Bods by Categorical Books

This will sort bods that you redeemed with my other script from resets, into categorically named bod books for easy retrieval when you are ready to use them to fill large bods.

You should review the script and make named bod books for each category.
 

Attachments

Joined
Mar 13, 2018
Messages
45
Likes
4
#9
Sort Tailoring Bods by Categorical Books

This will sort bods that you redeemed with my other script from resets, into categorically named bod books for easy retrieval when you are ready to use them to fill large bods.

You should review the script and make named bod books for each category.
 

Attachments

Joined
Mar 13, 2018
Messages
45
Likes
4
#10
Healing two pets with greater heal

This script will help you heal two pets with greater heal. It prioritizes the lowest health pet, and only heals if pets health is less than 90, and checks that you are in range.
 

Attachments

Joined
Mar 13, 2018
Messages
45
Likes
4
#11
Modified "bigheal" to use ArchCure instead of Cure

Self explanatory. Will check if you are poisoned, and use archcure instead of cure, if not poisoned, will cast greater heal on yourself.
 

Attachments

Joined
Mar 13, 2018
Messages
45
Likes
4
#12
Autotarget spellcast; or prompt for target if not found

Will autocast a spell on the object 'enemy'. If not found, will first prompt for the target then cast. Change the spell to make copies for different casting.
 

Attachments

Joined
Mar 13, 2018
Messages
45
Likes
4
#13
Get Enemy - used to auto-assign the closest likely bad guy as your "enemy" object, for use with autospellcasting:

Code:
getenemy 'murderer' 'enemy' 'criminal' 'gray' 'closest'
 
Joined
Mar 13, 2018
Messages
45
Likes
4
#14
Sort Items by Property

Will allow you to pull specific items (set up your pushlists accordingly) based on desired properties. I've set this up as an example to sort jewels.

Code:
//Author: Magus Zeal
//Sort Jewels based on desired property. Set aliases accordingly to secure or containers
//As example, I've set this up to separate jewels with both FC and FCR and jewels with just one of those properties
clearignorelist
promptalias 'src'
promptalias 'fcr_and_fc'
promptalias 'fcr_or_fc_or_mana'
@useobject 'fcr_and_fc'
@useobject 'fcr_or_fc_or_mana'
pause 1000
useobject 'src'
pause 1000
removelist 'ItemTypes'
createlist 'ItemTypes'
@pushlist 'ItemTypes' 0x1f06
@pushlist 'ItemTypes' 0x1086
@pushlist 'ItemTypes' 0x108a
@pushlist 'ItemTypes' 0x1f09
removelist 'property'
createlist 'property'
@pushlist 'property' "faster casting" //0
@pushlist 'property' "faster cast recovery" //1
@pushlist 'property' "mana regeneration" //2
// !!*** End of Data Init ***!!
for 0 to 'ItemTypes'
  while @findtype ItemTypes[] 'any' 'src'
    if property 'faster casting' 'found' and property 'faster cast recovery' 'found'
      @moveitem 'found' 'fcr_and_fc'
      pause 1000
    endif
    ignoreobject 'found'
  endwhile
endfor
clearignorelist
for 0 to 'ItemTypes'
  while @findtype ItemTypes[] 'any' 'src'
    if property 'faster casting' 'found' or property 'faster cast recovery' 'found'
      @moveitem 'found' 'fcr_or_fc_or_mana'
      pause 1000
    elseif property 'mana regeneration' 'found'
      @moveitem 'found' 'fcr_or_fc_or_mana'
      pause 1000
    endif
    ignoreobject 'found'
  endwhile
endfor
 
Joined
Mar 13, 2018
Messages
45
Likes
4
#15
Sort Magery Scrolls

Setup some bags, and sort your magery scrolls by circle. Can be used later with a spellbook filler script to pull scrolls and drop them into an empty book. All credit to Experience for the script.

Code:
//Author: Experience
//Description: Sort Scrolls by Circle
//Set-up: Have 1 Box with 8 bags inside
//modded by Magus Zeal to allow selection of a sort bag. But all credit goes to Experience
promptalias 'src'
useobject 'src'
pause 1000
headmsg 'Do you want to reset script? type "y"'
@clearjournal
pause 3000
if @injournal 'y'
  @unsetalias 'Scroll Storage'
  @unsetalias 'First Circle'
  @unsetalias 'Second Circle'
  @unsetalias 'Third Circle'
  @unsetalias 'Fourth Circle'
  @unsetalias 'Fifth Circle'
  @unsetalias 'Sixth Circle'
  @unsetalias 'Seventh Circle'
  @unsetalias 'Eighth Circle'
endif
if not @findobject 'Scroll Storage'
  headmsg 'Target container with the 8 Bags inside'
  promptalias 'Scroll Storage'
  pause 500
  @useobject 'Scroll Storage'
else
  @useobject 'Scroll Storage'
endif
if not @findobject 'First Circle'
  headmsg 'Target the bag for First Circle'
  promptalias 'First Circle'
endif
if not @findobject 'Second Circle'
  headmsg 'Target the bag for Second Circle'
  promptalias 'Second Circle'
endif
if not @findobject 'Third Circle'
  headmsg 'Target the bag for Third Circle'
  promptalias 'Third Circle'
endif
if not @findobject 'Fourth Circle'
  headmsg 'Target the bag for Fourth Circle'
  promptalias 'Fourth Circle'
endif
if not @findobject 'Fifth Circle'
  headmsg 'Target the bag for Fifth Circle'
  promptalias 'Fifth Circle'
endif
if not @findobject 'Sixth Circle'
  headmsg 'Target the bag for Sixth Circle'
  promptalias 'Sixth Circle'
endif
if not @findobject 'Seventh Circle'
  headmsg 'Target the bag for Seventh Circle'
  promptalias 'Seventh Circle'
endif
if not @findobject 'Eighth Circle'
  headmsg 'Target the bag for Eighth Circle'
  promptalias 'Eighth Circle'
endif
if not @listexists 'FirstCircle'
  createlist 'FirstCircle'
  @pushlist 'FirstCircle' 0x1f2e // Clumsy
  @pushlist 'FirstCircle' 0x1f2f // Create Food
  @pushlist 'FirstCircle' 0x1f30 // Feeblemind
  @pushlist 'FirstCircle' 0x1f31 // Heal
  @pushlist 'FirstCircle' 0x1f32 // Magic Arrow
  @pushlist 'FirstCircle' 0x1f33 // Night Sight
  @pushlist 'FirstCircle' 0x1f2d // Reactive Armor
  @pushlist 'FirstCircle' 0x1f34 // Weaken
endif
if not @listexists 'SecondCircle'
  createlist 'SecondCircle'
  @pushlist 'SecondCircle' 0x1f35 // Agility
  @pushlist 'SecondCircle' 0x1f36 // Cunning
  @pushlist 'SecondCircle' 0x1f37 // Cure
  @pushlist 'SecondCircle' 0x1f38 // Harm
  @pushlist 'SecondCircle' 0x1f39 // Magic Trap
  @pushlist 'SecondCircle' 0x1f3a // Magic Untrap
  @pushlist 'SecondCircle' 0x1f3b // Protection
  @pushlist 'SecondCircle' 0x1f3c // Strength
endif
if not @listexists 'ThirdCircle'
  createlist 'ThirdCircle'
  @pushlist 'ThirdCircle' 0x1f3d // Bless
  @pushlist 'ThirdCircle' 0x1f3e // Fireball
  @pushlist 'ThirdCircle' 0x1f3f // Magic Lock
  @pushlist 'ThirdCircle' 0x1f40 // Poison
  @pushlist 'ThirdCircle' 0x1f41 // Telekinesis
  @pushlist 'ThirdCircle' 0x1f42 // Teleport
  @pushlist 'ThirdCircle' 0x1f43 // Unlock
  @pushlist 'ThirdCircle' 0x1f44 // Wall of Stone
endif
if not @listexists 'FourthCircle'
  createlist 'FourthCircle'
  @pushlist 'FourthCircle' 0x1f45 // Arch Cure
  @pushlist 'FourthCircle' 0x1f46 // Arch Protection
  @pushlist 'FourthCircle' 0x1f47 // Curse
  @pushlist 'FourthCircle' 0x1f48 // Fire Field
  @pushlist 'FourthCircle' 0x1f49 // Greater Heal
  @pushlist 'FourthCircle' 0x1f4a // Lightning
  @pushlist 'FourthCircle' 0x1f4b // Mana Drain
  @pushlist 'FourthCircle' 0x1f4c // Recall
endif
if not @listexists 'FifthCircle'
  createlist 'FifthCircle'
  @pushlist 'FifthCircle' 0x1f4d // Blade Spirit
  @pushlist 'FifthCircle' 0x1f4e // Dispel Field
  @pushlist 'FifthCircle' 0x1f4f // Incognito
  @pushlist 'FifthCircle' 0x1f50 // Magic Reflection
  @pushlist 'FifthCircle' 0x1f51 // Mind Blast
  @pushlist 'FifthCircle' 0x1f52 // Paralyze
  @pushlist 'FifthCircle' 0x1f53 // Poison Field
  @pushlist 'FifthCircle' 0x1f54 // Summon Creature
endif
if not @listexists 'SixthCircle'
  createlist 'SixthCircle'
  @pushlist 'SixthCircle' 0x1f55 // Dispel
  @pushlist 'SixthCircle' 0x1f56 // Energy Bolt
  @pushlist 'SixthCircle' 0x1f57 // Explosion
  @pushlist 'SixthCircle' 0x1f58 // Invisibility
  @pushlist 'SixthCircle' 0x1f59 // Mark
  @pushlist 'SixthCircle' 0x1f5a // Mass Curse
  @pushlist 'SixthCircle' 0x1f5b // Paralyze Field
  @pushlist 'SixthCircle' 0x1f5c // Reveal
endif
if not @listexists 'SeventhCircle'
  createlist 'SeventhCircle'
  @pushlist 'SeventhCircle' 0x1f5d // Chain Lightning
  @pushlist 'SeventhCircle' 0x1f5e // Energy Field
  @pushlist 'SeventhCircle' 0x1f5f // Flamestrike
  @pushlist 'SeventhCircle' 0x1f60 // Gate Travel
  @pushlist 'SeventhCircle' 0x1f61 // Mana Vampire
  @pushlist 'SeventhCircle' 0x1f62 // Mass Dispel
  @pushlist 'SeventhCircle' 0x1f63 // Meteor Swarm
  @pushlist 'SeventhCircle' 0x1f64 // Polymorph
endif
if not @listexists 'EighthCircle'
  createlist 'EighthCircle'
  @pushlist 'EighthCircle' 0x1f65 // Earthquake
  @pushlist 'EighthCircle' 0x1f66 // Energy Vortex
  @pushlist 'EighthCircle' 0x1f67 // Ressurrection
  @pushlist 'EighthCircle' 0x1f68 // Summon Air Elemental
  @pushlist 'EighthCircle' 0x1f69 // Summon Daemon
  @pushlist 'EighthCircle' 0x1f6a // Summon Earth Elemental
  @pushlist 'EighthCircle' 0x1f6b // Summon Fire Elemental
  @pushlist 'EighthCircle' 0x1f6c // Summon Water Elemental
endif
@useobject 'Scroll Storage'
pause 900
for 0 to FirstCircle
  if @movetype 'FirstCircle[]' 'src' 'First Circle'
    pause 800
  endif
endfor
for 0 to SecondCircle
  if @movetype 'SecondCircle[]' 'src' 'Second Circle'
    pause 800
  endif
endfor
for 0 to ThirdCircle
  if @movetype 'ThirdCircle[]' 'src' 'Third Circle'
    pause 800
  endif
endfor
for 0 to FourthCircle
  if @movetype 'FourthCircle[]' 'src' 'Fourth Circle'
    pause 800
  endif
endfor
for 0 to FifthCircle
  if @movetype 'FifthCircle[]' 'src' 'Fifth Circle'
    pause 800
  endif
endfor
for 0 to SixthCircle
  if @movetype 'SixthCircle[]' 'src' 'Sixth Circle'
    pause 800
  endif
endfor
for 0 to SeventhCircle
  if @movetype 'SeventhCircle[]' 'src' 'Seventh Circle'
    pause 800
  endif
endfor
for 0 to EighthCircle
  if @movetype 'EighthCircle[]' 'src' 'Eighth Circle'
    pause 800
  endif
endfor
headmsg 'I think we are done here'
stop
 
Joined
Mar 13, 2018
Messages
45
Likes
4
#16
Train Magery

You might need to tweak pauses based on FC/FCR.

Code:
//Author: Magus Zeal
//Train Magery based on UOGuide recommendations
//Run with loop checked
if mana < 20
  useskill 'meditation'
  while mana < maxmana
  endwhile
endif
if hits < 40
  cast "Greater Heal"
  waitingfortarget
  target 'self'
  pause 1000
endif
if skill 'magery' < 45
  cast "Bless"
  waitingfortarget
  target 'self'
  pause 3000
elseif skill 'magery' < 55
  cast "Mana Drain"
  waitingfortarget
  target 'self'
  pause 3500
elseif skill 'magery' < 65
  cast "Paralyze"
  waitingfortarget
  target 'self'
  pause 3500
elseif skill 'magery' < 75
  cast "Reveal"
  waitingfortarget
  target 'self'
  pause 4000
elseif skill 'magery' < 90
  cast "Mana Vampire"
  waitingfortarget
  target 'self'
  pause 4000
elseif skill 'magery' < 100
  cast "Earthquake"
  waitingfortarget
  pause 4500
endif
//add one more iteration of Earthquake, or use masteries for 100-120
stop
 
Joined
Mar 13, 2018
Messages
45
Likes
4
#17
Train Necromancy

Like magery, tweak pauses as needed.

Code:
//Author: Magus Zeal
//Train Necromancy
//Tweak pauses, and mana/hits thresholds as needed
//Run with loop checked
if mana < 40
  useskill 'meditation'
  while mana < maxmana
  endwhile
endif
if hits < 40
  cast "Greater Heal"
  waitingfortarget
  target 'self'
  pause 1000
endif
if skill 'necromancy' < 50
  cast "Pain Spike"
  waitingfortarget
  target 'self'
  pause 3000
elseif skill 'necromancy' < 70
  cast "Horrific Beast"
  pause 3500
elseif skill 'necromancy' < 90
  cast "Wither"
  waitingfortarget
  target 'self'
  pause 3500
elseif skill 'necromancy' < 100
  cast "Lich Form"
  waitingfortarget
  target 'self'
  pause 4000
endif
//Add iteration of Lich form here or use masteries for training above 100
stop
 
Joined
Mar 13, 2018
Messages
45
Likes
4
#18
Make full spellbooks with GM scribe - all credit to author:

Code:
//===============================================================
//=---------------------Spell Book Maker------------------------=
//=-------------------------By:Hawt-----------------------------=
//=-------------------------------------------------------------=
//=--------This script will make scrolls 1-64, Place them-------=
//=-----------in the book, meditate, and adjust when------------=
//=----to use mediation Based on what scrolls you are making----=
//=----I have broke the script down pretty good in order for----=
//=--------others to learn from 'dissecting' the script --------=
//=-------------------------------------------------------------=
//===============================================================
//=Gives Target for you too select the spellbook you want filled=
//===============================================================
if not @findobject 'spellbook'
  sysmsg '!!!! Target Empty Spell Book !!!!' '23'
  promptalias 'spellbook'
endif
//===============================================================
//=-----List of the gump buttons for the 8 Spell Circles.-------=
//===============================================================
if not listexists 'Circle'
  @createlist 'Circle'
endif
if 'list' 'Circle' == '0'
  @pushlist 'Circle' '1'
  @pushlist 'Circle' '8'
  @pushlist 'Circle' '15'
  @pushlist 'Circle' '22'
endif
//==============================================================
//=--------List of the gump buttons for each scroll------------=
//==============================================================
if not listexists 'Spells'
  @createlist 'Spells'
endif
if 'list' 'Spells' == '0'
  @pushlist 'Spells' '2'
  @pushlist 'Spells' '9'
  @pushlist 'Spells' '16'
  @pushlist 'Spells' '23'
  @pushlist 'Spells' '30'
  @pushlist 'Spells' '37'
  @pushlist 'Spells' '44'
  @pushlist 'Spells' '51'
  @pushlist 'Spells' '58'
  @pushlist 'Spells' '65'
  @pushlist 'Spells' '72'
  @pushlist 'Spells' '79'
  @pushlist 'Spells' '86'
  @pushlist 'Spells' '93'
  @pushlist 'Spells' '100'
  @pushlist 'Spells' '107'
endif
//==============================================================
//=-------------List of different Mana lvls--------------------=
//==============================================================
if not listexists 'Mana'
  @createlist 'Mana'
endif
if 'list' 'Mana' == '0'
  @pushlist 'Mana' '4'
  @pushlist 'Mana' '6'
  @pushlist 'Mana' '9'
  @pushlist 'Mana' '11'
  @pushlist 'Mana' '14'
  @pushlist 'Mana' '20'
  @pushlist 'Mana' '40'
  @pushlist 'Mana' '50'
endif
//==============================================================
//=--------------List all Scrolls for each spell---------------=
//==============================================================
//=----------I did not make this list i took the list----------=
//=------------from another in The script library--------------=
//=-------------------Thank you Kadoba!!-----------------------=
//=http://www.runuo.com/community/resources/fill-spellbook.57/-=
//==============================================================
if not listexists 'scrolls'
  @createlist 'scrolls'
endif
if 'list' 'scrolls' == '0'
  @pushlist 'scrolls' 0x1f2d // Reactive Armor
  @pushlist 'scrolls' 0x1f2e // Clumsy
  @pushlist 'scrolls' 0x1f2f // Create Food
  @pushlist 'scrolls' 0x1f30 // Feeblemind
  @pushlist 'scrolls' 0x1f31 // Heal
  @pushlist 'scrolls' 0x1f32 // Magic Arrow
  @pushlist 'scrolls' 0x1f33 // Night Sight
  @pushlist 'scrolls' 0x1f34 // Weaken
  @pushlist 'scrolls' 0x1f35 // Agility
  @pushlist 'scrolls' 0x1f36 // Cunning
  @pushlist 'scrolls' 0x1f37 // Cure
  @pushlist 'scrolls' 0x1f38 // Harm
  @pushlist 'scrolls' 0x1f39 // Magic Trap
  @pushlist 'scrolls' 0x1f3a // Magic Untrap
  @pushlist 'scrolls' 0x1f3b // Protection
  @pushlist 'scrolls' 0x1f3c // Strength
  @pushlist 'scrolls' 0x1f3d // Bless
  @pushlist 'scrolls' 0x1f3e // Fireball
  @pushlist 'scrolls' 0x1f3f // Magic Lock
  @pushlist 'scrolls' 0x1f40 // Poison
  @pushlist 'scrolls' 0x1f41 // Telekinesis
  @pushlist 'scrolls' 0x1f42 // Teleport
  @pushlist 'scrolls' 0x1f43 // Unlock
  @pushlist 'scrolls' 0x1f44 // Wall of Stone
  @pushlist 'scrolls' 0x1f45 // Arch Cure
  @pushlist 'scrolls' 0x1f46 // Arch Protection
  @pushlist 'scrolls' 0x1f47 // Curse
  @pushlist 'scrolls' 0x1f48 // Fire Field
  @pushlist 'scrolls' 0x1f49 // Greater Heal
  @pushlist 'scrolls' 0x1f4a // Lightning
  @pushlist 'scrolls' 0x1f4b // Mana Drain
  @pushlist 'scrolls' 0x1f4c // Recall
  @pushlist 'scrolls' 0x1f4d // Blade Spirit
  @pushlist 'scrolls' 0x1f4e // Dispel Field
  @pushlist 'scrolls' 0x1f4f // Incognito
  @pushlist 'scrolls' 0x1f50 // Magic Reflection
  @pushlist 'scrolls' 0x1f51 // Mind Blast
  @pushlist 'scrolls' 0x1f52 // Paralyze
  @pushlist 'scrolls' 0x1f53 // Poison Field
  @pushlist 'scrolls' 0x1f54 // Summon Creature
  @pushlist 'scrolls' 0x1f55 // Dispel
  @pushlist 'scrolls' 0x1f56 // Energy Bolt
  @pushlist 'scrolls' 0x1f57 // Explosion
  @pushlist 'scrolls' 0x1f58 // Invisibility
  @pushlist 'scrolls' 0x1f59 // Mark
  @pushlist 'scrolls' 0x1f5a // Mass Curse
  @pushlist 'scrolls' 0x1f5b // Paralyze Field
  @pushlist 'scrolls' 0x1f5c // Reveal
  @pushlist 'scrolls' 0x1f5d // Chain Lightning
  @pushlist 'scrolls' 0x1f5e // Energy Field
  @pushlist 'scrolls' 0x1f5f // Flamestrike
  @pushlist 'scrolls' 0x1f60 // Gate Travel
  @pushlist 'scrolls' 0x1f61 // Mana Vampire
  @pushlist 'scrolls' 0x1f62 // Mass Dispel
  @pushlist 'scrolls' 0x1f63 // Meteor Swarm
  @pushlist 'scrolls' 0x1f64 // Polymorph
  @pushlist 'scrolls' 0x1f65 // Earthquake
  @pushlist 'scrolls' 0x1f66 // Energy Vortex
  @pushlist 'scrolls' 0x1f67 // Ressurrection
  @pushlist 'scrolls' 0x1f68 // Summon Air Elemental
  @pushlist 'scrolls' 0x1f69 // Summon Daemon
  @pushlist 'scrolls' 0x1f6a // Summon Earth Elemental
  @pushlist 'scrolls' 0x1f6b // Summon Fire Elemental
  @pushlist 'scrolls' 0x1f6c // Summon Water Elemental
endif
//===============================================================
//=-------Basically telling the script when to meditate---------=
//===============================================================
if @ingump 0x38920abd 'required mana'
  useskill 'meditation'
  while not mana == maxmana
  endwhile
endif
//===============================================================
//=-----------------Checks for Blank Scrolls.-------------------=
//===============================================================
if not @findtype '0xef3' 'any' 'backpack'
  sysmsg '#### No Scrolls###'
  stop
endif
//===============================================================
//=---Checks for Scribe Pens, if finding one is uses the pen.---=
//===============================================================
if @usetype '0xfbf' 'any' 'backpack'
  waitforgump '0x38920abd' '5000'
else
  sysmsg '####No Pens ####' '23'
  stop
endif
//==============================================================
//=-----------------Gump Buttons to be pressed.----------------=
//==============================================================
replygump '0x38920abd' Circle[0]
waitforgump '0x38920abd' '5000'
replygump '0x38920abd' Spells[0]
waitforgump '0x38920abd' '5000'
pause 900
//==============================================================
//=------------Checks for Scroll to be placed in book----------=
//==============================================================
if @movetype scrolls[0] 'backpack' 'spellbook' 0 0 0 'any' '1'
  pause '1000'
  poplist 'Spells' 'front'
  poplist 'scrolls' 'front'
endif
//==============================================================
//=--------After Finishing a complete circle of spells---------=
//=-----This changes the Spell Circle and When to meditate.----=
//==============================================================
if list 'Spells' == 0
  poplist 'Circle' 'front'
  poplist 'Mana' 'front'
endif
//==============================================================
//=----This stops the script when completeing a full book.-----=
//==============================================================
if list 'scrolls' == 0
  unsetalias 'spellbook'
  sysmsg 'Spell Book Should Be Full' '23'
  stop
endif
 
Joined
Mar 13, 2018
Messages
45
Likes
4
#19
Tamer Helper - Will tame animals around you and follow them until tamed, then will rename them for you. All credit to author

Code:
//TamerHelpervUOF By Vlek, Grunt of the Bloodclan (Bloodclan.org)
//Get close to your target, press your associated key.
//CAUTION: Must watch this script. It's not as intelligent as the regular one.
if not listexists 'NameTheTamed'
  //Set this name to whatever you want.
  createlist 'NameTheTamed'
  pushlist 'NameTheTamed' 'Squirrel'
endif
if not listexists 'tameables'
  createlist 'tameables'
  pushlist 'tameables' 0x7t //Hellcat (Large)
  pushlist 'tameables' 0x62 //Hellhound
  pushlist 'tameables' 0xbc //Savage Ridgeback
  pushlist 'tameables' 0xbb //Ridgeback
  pushlist 'tameables' 0x17 //Dire Wolf
  pushlist 'tameables' 0xce //Lava Lizard
  pushlist 'tameables' 0x14 //Frost spider
  pushlist 'tameables' 0xc9 //Hellcat (Small)
  pushlist 'tameables' 0xda //Frenzied Ostard
  pushlist 'tameables' 0x50 //Giant Toad
  pushlist 'tameables' 0xe8 //Bull
  pushlist 'tameables' 0xe9 //Bull2
  pushlist 'tameables' 0x22 //White Wolf
  pushlist 'tameables' 0x25 //White Wolf2
  pushlist 'tameables' 0x1c //Giant Spider
  pushlist 'tameables' 0xd4 //Grizzly Bear
  pushlist 'tameables' 0xea //Great Hart
  pushlist 'tameables' 0x41 //Snow leopard
  pushlist 'tameables' 0x40 //Snow leopard
  pushlist 'tameables' 0x19 //Gray wolf
  pushlist 'tameables' 0x1b //Gray wolf2
  pushlist 'tameables' 0x30 //Scorpion
  pushlist 'tameables' 0xca //Alligator
  pushlist 'tameables' 0x3f //Cougar
  pushlist 'tameables' 0xd6 //Panther
  pushlist 'tameables' 0xa7 //Brown Bear
  pushlist 'tameables' 0xdd //Walrus
  pushlist 'tameables' 0xd5 //Polar Bear
  pushlist 'tameables' 0xd3 //Black Bear
  pushlist 'tameables' //0xdc //Llama
  pushlist 'tameables' 0x124 //Pack Llama
  pushlist 'tameables' 0x123 //Pack Horse
  pushlist 'tameables' 0xc8 //Horse
  pushlist 'tameables' 0xe2 //Horse2
  pushlist 'tameables' 0xcc //Horse3
  pushlist 'tameables' //0xed //Giant Rat
  pushlist 'tameables' 0xdb //Forest Ostard
  pushlist 'tameables' 0xd2 //Desert Ostard
  pushlist 'tameables' 0x122 //Boar
  pushlist 'tameables' 0xe1 //Timber Wolf
  //  pushlist 'tameables' 0xed //Hind
  pushlist 'tameables' 0x51 //Bullfrog
endif
if not @inrange 'tobetamed' 2
  @unsetalias 'tobetamed'
  for 0 in 'tameables'
    if @findtype tameables[] 'any' 'ground' 1 2
      @setalias 'tobetamed' 'found'
      break
    endif
  endfor
endif
if not @inrange 'tobetamed' 2
  headmsg 'No new creatures near you!'
  replay
endif
clearjournal
while name 'tobetamed' != NameTheTamed[0]
  autotargetobject 'tobetamed'
  useskill 'animal taming'
  @rename 'tobetamed' NameTheTamed[0]
  pause 1000
  if not @inrange 'tobetamed' 1
    if @x 'tobetamed' > x 'self' and @y 'tobetamed' > y 'self'
      walk 'Southeast'
    elseif @x 'tobetamed' < x 'self' and @y 'tobetamed' > y 'self'
      walk 'Southwest'
    elseif @x 'tobetamed' > x 'self' and @y 'tobetamed' < y 'self'
      walk 'Northeast'
    elseif @x 'tobetamed' < x 'self' and @y 'tobetamed' < y 'self'
      walk 'Northwest'
    elseif @x 'tobetamed' > x 'self' and @y 'tobetamed' == y 'self'
      walk 'East'
    elseif @x 'tobetamed' < x 'self' and @y 'tobetamed' == y 'self'
      walk 'West'
    elseif @x 'tobetamed' == x 'self' and @y 'tobetamed' > y 'self'
      walk 'South'
    elseif @x 'tobetamed' == x 'self' and @y 'tobetamed' < y 'self'
      walk 'North'
    endif
  endif
endwhile
waitforcontext 'tobetamed' 9 20000
waitforgump 0x909cc741 15000
@replygump 0x909cc741 2
@ignoreobject 'tobetamed'
@unsetalias 'tobetamed'
replay